¿Cómo se obtiene una vista dinámica de 12 días hábiles en Postgresql?

Esto se puede solucionar con un CTE:

WITH business_days_back AS (
  WITH RECURSIVE bd(back_day, go_back) AS (
    -- Go back to the previous Monday, allowing for current_date in the weekend
    SELECT CASE extract(dow from current_date)
             WHEN 0 THEN current_date - 6
             WHEN 6 THEN current_date - 5
             ELSE current_date - extract(dow from current_date)::int + 1
           END,
           CASE extract(dow from current_date)
             WHEN 0 THEN 7
             WHEN 6 THEN 7
             ELSE 12 - extract(dow from current_date)::int + 1
           END
    UNION
    -- Go back by the week until go_back = 0
    SELECT CASE
         WHEN go_back >= 5 THEN back_day - 7
         WHEN go_back > 0 THEN back_day - 2 - go_back
       END,
       CASE
         WHEN go_back >= 5 THEN go_back - 5
         WHEN go_back > 0 THEN 0
       END
    FROM bd
  )
  SELECT back_day FROM bd WHERE go_back = 0
)
SELECT * FROM my_table WHERE analysis_date >= (SELECT * FROM business_days_back);

Alguna explicación:

• El CTE interno comienza volviendo al lunes anterior, compensando una current_date que cae en un día de fin de semana.
• El término recursivo luego agrega filas retrocediendo semanas completas (back_day - 7 para la fecha del calendario y go_back - 5 para los días hábiles) hasta go_back = 0 .
• El CTE externo devuelve el back_day fecha donde go_back = 0 . Por lo tanto, esta es una consulta escalar y puede usarla como una subconsulta en una expresión de filtro.

Puede cambiar la cantidad de días hábiles para mirar hacia atrás simplemente cambiando los números 12 y 7 en el SELECT inicial en el CTE interior. Sin embargo, tenga en cuenta que el valor debe ser tal que vuelva al lunes anterior o la consulta fallará debido al mismo SELECT inicial del CTE interior.

Una solución mucho más flexible (y probablemente más rápida*) es usar la siguiente función:

CREATE FUNCTION business_days_diff(from_date date, diff int) RETURNS date AS $$
-- This function assumes Mon-Fri business days
DECLARE
  start_dow int;
  calc_date date;
  curr_diff int;
  weekend   int;
BEGIN
  -- If no diff requested, return the from_date. This may be a non-business day.
  IF diff = 0 THEN
    RETURN from_date;
  END IF;

  start_dow := extract(dow from from_date)::int;
  calc_date := from_date;

  IF diff < 0 THEN -- working backwards
    weekend := -2;
    IF start_dow = 0 THEN -- Fudge initial Sunday to the previous Saturday
      calc_date := calc_date - 1;
      start_dow := 6;
    END IF;
    IF start_dow + diff >= 1 THEN -- Stay in this week
      RETURN calc_date + diff;
    ELSE                             -- Work back to Monday
      calc_date := calc_date - start_dow + 1;
      curr_diff := diff + start_dow - 1;
    END IF;
  ELSE -- Working forwards
    weekend := 2;
    IF start_dow = 6 THEN -- Fudge initial Saturday to the following Sunday
      calc_date := calc_date + 1;
      start_dow := 0;
    END IF;
    IF start_dow + diff <= 5 THEN -- Stay in this week
      RETURN calc_date + diff;
    ELSE                             -- Work forwards to Friday
      calc_date := calc_date + 5 - start_dow;
      curr_diff := diff - 5 + start_dow;
    END IF;
  END IF;

  -- Move backwards or forwards by full weeks
  calc_date := calc_date + (curr_diff / 5) * 7;

  -- Process any remaining days, include weekend
  IF curr_diff % 5 != 0 THEN
    RETURN calc_date + curr_diff % 5 + weekend;
  ELSE
    RETURN calc_date;
  END IF;
END; $$ LANGUAGE plpgsql STRICT IMMUTABLE;

Esta función puede tomar cualquier fecha para calcular desde y cualquier número de días en el futuro (valor positivo de diff ) o el pasado (valor negativo de diff ), incluidas las diferencias dentro de la semana actual. Y dado que devuelve la fecha del día hábil como un escalar, el uso en su consulta es muy sencillo:

SELECT * 
FROM table
WHERE analysis_date >= business_days_diff(current_date, -12);

Aparte de eso, también puede pasar campos desde su tabla y hacer cosas divertidas como:

SELECT t1.some_value - t2.some_value AS value_diff
FROM table t1
JOIN table t2 ON t2.analysis_date = business_days_diff(t1.analysis_date, -12);

es decir, una autounión en una cierta cantidad de días hábiles de separación.

Tenga en cuenta que esta función asume una semana laboral de lunes a viernes.

_{* Esta función solo hace aritmética simple en valores escalares. El CTE tiene que configurar todo tipo de estructuras para soportar la iteración y los conjuntos de registros resultantes.}