Codificación clásica ASP, MySQL u ODBC UTF8

Tienes la oportunidad de obtener letras eslovenas de acuerdo con este mapping y un extracto del artículo wiki de Windows-1252 :

Esto es lo que hay que hacer:

1. Utilice archivos codificados en UTF-8 (sin BOM) contra la posibilidad de que contengan texto codificado. (✔ ya hecho)

2. Especifique UTF-8 para el juego de caracteres de respuesta con ASP en el lado del servidor o con etiquetas meta en el lado del cliente. (✔ ya hecho)

3. Dígale al servidor MySQL que sus comandos están en charset utf-8, y espera conjuntos de resultados codificados en utf-8. Agregue una declaración inicial a la cadena de conexión:...;stmt=SET NAMES 'utf8';...

4. Establezca Response.CodePage en 1252.

He probado el siguiente script y funciona de maravilla.

DDL: http://sqlfiddle.com/#!8/c2c35/1

ASP:

<%@Language=VBScript%>
<% 
Option Explicit

Response.CodePage = 1252
Response.LCID = 1060
Response.Charset = "utf-8"

Const adCmdText = 1, adVarChar = 200, adParamInput = 1, adLockOptimistic = 3

Dim Connection
Set Connection = Server.CreateObject("Adodb.Connection")
    Connection.Open "Driver={MySQL ODBC 3.51 Driver};Server=localhost;Database=myDb;User=myUsr;Password=myPwd;stmt=SET NAMES 'utf8';"
    
If Request.Form("name").Count = 1 And Len(Request.Form("name")) Then 'add new
    Dim rsAdd
    Set rsAdd = Server.CreateObject("Adodb.Recordset")
        rsAdd.Open "names", Connection, ,adLockOptimistic
        rsAdd.AddNew
        rsAdd("name").Value = Left(Request.Form("name"), 255)
        rsAdd.Update
        rsAdd.Close
    Set rsAdd = Nothing
End If

Dim Command
Set Command = Server.CreateObject("Adodb.Command")
    Command.CommandType = adCmdText
    Command.CommandText = "Select name From `names` Order By id Desc"
    
    If Request.QueryString("name").Count = 1 And Len(Request.QueryString("name")) Then
        Command.CommandText = "Select name From `names` Where name = ? Order By id Desc"
        Command.Parameters.Append Command.CreateParameter(, adVarChar, adParamInput, 255, Left(Request.QueryString("name"), 255))
    End If
    
    Set Command.ActiveConnection = Connection
    With Command.Execute
        While Not .Eof
            Response.Write "<a href=""?name=" & .Fields("name").Value & """>" & .Fields("name").Value & "</a><br />"
            .MoveNext
        Wend
        .Close
    End With
    
    Set Command.ActiveConnection = Nothing
    Set Command = Nothing
    
Connection.Close
%><hr />
<a href="?">SHOW ALL</a><hr />
<form method="post" action="<%=Request.ServerVariables("SCRIPT_NAME")%>">
Name : <input type="text" name="name" maxlength="255" /> <input type="submit" value="Add" />
</form>

Como última observación:

Cuando necesite aplicar la codificación html a las cadenas obtenidas de la base de datos, ya no debe usar Server.HTMLEncode debido a que Response.Codepage es 1252 en el lado del servidor y dado que Server.HTMLEncode es una página de códigos de contexto dependiente, esto provocará resultados incomprensibles.
Entonces necesitará escribir su propio codificador html para manejar el caso.

Function MyOwnHTMLEncode(ByVal str)
    str = Replace(str, "&", "&")
    str = Replace(str, "<", "&lt;")
    str = Replace(str, ">", "&gt;")
    str = Replace(str, """", "&quot;")
    MyOwnHTMLEncode = str
End Function
'Response.Write MyOwnHTMLEncode(rs("myfield").value)