Hay dos usos para RAISE_APPLICATION_ERROR. El primero es reemplazar los mensajes genéricos de excepción de Oracle con nuestros propios mensajes más significativos. El segundo es crear nuestras propias condiciones de excepción, cuando Oracle no las lanzaría.
El siguiente procedimiento ilustra ambos usos. Hace cumplir una regla comercial de que no se pueden contratar nuevos empleados en el futuro. También anula dos excepciones de Oracle. Uno es DUP_VAL_ON_INDEX, que se genera mediante una clave única en EMP(ENAME) . La otra es una excepción definida por el usuario lanzada cuando la clave externa entre EMP(MGR) y EMP(EMPNO) se infringe (porque un gerente debe ser un empleado existente).
create or replace procedure new_emp
( p_name in emp.ename%type
, p_sal in emp.sal%type
, p_job in emp.job%type
, p_dept in emp.deptno%type
, p_mgr in emp.mgr%type
, p_hired in emp.hiredate%type := sysdate )
is
invalid_manager exception;
PRAGMA EXCEPTION_INIT(invalid_manager, -2291);
dummy varchar2(1);
begin
-- check hiredate is valid
if trunc(p_hired) > trunc(sysdate)
then
raise_application_error
(-20000
, 'NEW_EMP::hiredate cannot be in the future');
end if;
insert into emp
( ename
, sal
, job
, deptno
, mgr
, hiredate )
values
( p_name
, p_sal
, p_job
, p_dept
, p_mgr
, trunc(p_hired) );
exception
when dup_val_on_index then
raise_application_error
(-20001
, 'NEW_EMP::employee called '||p_name||' already exists'
, true);
when invalid_manager then
raise_application_error
(-20002
, 'NEW_EMP::'||p_mgr ||' is not a valid manager');
end;
/
Cómo se ve:
SQL> exec new_emp ('DUGGAN', 2500, 'SALES', 10, 7782, sysdate+1)
BEGIN new_emp ('DUGGAN', 2500, 'SALES', 10, 7782, sysdate+1); END;
*
ERROR at line 1:
ORA-20000: NEW_EMP::hiredate cannot be in the future
ORA-06512: at "APC.NEW_EMP", line 16
ORA-06512: at line 1
SQL>
SQL> exec new_emp ('DUGGAN', 2500, 'SALES', 10, 8888, sysdate)
BEGIN new_emp ('DUGGAN', 2500, 'SALES', 10, 8888, sysdate); END;
*
ERROR at line 1:
ORA-20002: NEW_EMP::8888 is not a valid manager
ORA-06512: at "APC.NEW_EMP", line 42
ORA-06512: at line 1
SQL>
SQL> exec new_emp ('DUGGAN', 2500, 'SALES', 10, 7782, sysdate)
PL/SQL procedure successfully completed.
SQL>
SQL> exec new_emp ('DUGGAN', 2500, 'SALES', 10, 7782, sysdate)
BEGIN new_emp ('DUGGAN', 2500, 'SALES', 10, 7782, sysdate); END;
*
ERROR at line 1:
ORA-20001: NEW_EMP::employee called DUGGAN already exists
ORA-06512: at "APC.NEW_EMP", line 37
ORA-00001: unique constraint (APC.EMP_UK) violated
ORA-06512: at line 1
Tenga en cuenta la salida diferente de las dos llamadas a RAISE_APPLICATION_ERROR en el bloque EXCEPTIONS. Establecer el tercer argumento opcional en TRUE significa que RAISE_APPLICATION_ERROR incluye la excepción de activación en la pila, lo que puede ser útil para el diagnóstico.
Hay más información útil en la Guía del usuario de PL/SQL.
