El recuento de transacciones después de EXECUTE indica un número no coincidente de instrucciones BEGIN y COMMIT. Conteo anterior =1, conteo actual =0

Si tiene un bloque TRY/CATCH, la causa probable es que está detectando una excepción de cancelación de transacción y continúa. En el bloque CATCH siempre debe marcar el XACT_STATE() y manejar transacciones abortadas y no comprometidas (condenadas) apropiadas. Si la persona que llama inicia una transacción y la persona que recibe la llamada llega, por ejemplo, a un interbloqueo (que abortó la transacción), ¿cómo le comunicará la persona que llama a la persona que llama que la transacción fue abortada y que no debe continuar con "negocios como de costumbre"? La única forma factible es volver a generar una excepción, obligando a la persona que llama a manejar la situación. Si traga silenciosamente una transacción abortada y la persona que llama continúa asumiendo que todavía está en la transacción original, solo el caos puede asegurarlo (y el error que obtiene es la forma en que el motor intenta protegerse).

Le recomiendo que revise Manejo de excepciones y transacciones anidadas que muestra un patrón que se puede usar con transacciones anidadas y excepciones:

create procedure [usp_my_procedure_name]
as
begin
    set nocount on;
    declare @trancount int;
    set @trancount = @@trancount;
    begin try
        if @trancount = 0
            begin transaction
        else
            save transaction usp_my_procedure_name;

        -- Do the actual work here

lbexit:
        if @trancount = 0
            commit;
    end try
    begin catch
        declare @error int, @message varchar(4000), @xstate int;
        select @error = ERROR_NUMBER(), @message = ERROR_MESSAGE(), @xstate = XACT_STATE();
        if @xstate = -1
            rollback;
        if @xstate = 1 and @trancount = 0
            rollback
        if @xstate = 1 and @trancount > 0
            rollback transaction usp_my_procedure_name;

        raiserror ('usp_my_procedure_name: %d: %s', 16, 1, @error, @message) ;
    end catch
end
go