SQL Server:haga todas las mayúsculas en mayúsculas y minúsculas o mayúsculas y minúsculas

Esta función:

• "Casos apropiados" todas las palabras en "MAYÚSCULAS" que están delimitadas por espacios en blanco
• deja las "palabras en minúsculas" solas
• funciona correctamente incluso para alfabetos distintos del inglés
• es portátil en el sentido de que no utiliza características sofisticadas de versiones recientes del servidor SQL
• se puede cambiar fácilmente para usar NCHAR y NVARCHAR para compatibilidad con Unicode, así como cualquier longitud de parámetro que considere adecuada
• la definición de espacios en blanco se puede configurar

CREATE FUNCTION ToProperCase(@string VARCHAR(255)) RETURNS VARCHAR(255)
AS
BEGIN
  DECLARE @i INT           -- index
  DECLARE @l INT           -- input length
  DECLARE @c NCHAR(1)      -- current char
  DECLARE @f INT           -- first letter flag (1/0)
  DECLARE @o VARCHAR(255)  -- output string
  DECLARE @w VARCHAR(10)   -- characters considered as white space

  SET @w = '[' + CHAR(13) + CHAR(10) + CHAR(9) + CHAR(160) + ' ' + ']'
  SET @i = 1
  SET @l = LEN(@string)
  SET @f = 1
  SET @o = ''

  WHILE @i <= @l
  BEGIN
    SET @c = SUBSTRING(@string, @i, 1)
    IF @f = 1 
    BEGIN
     SET @o = @o + @c
     SET @f = 0
    END
    ELSE
    BEGIN
     SET @o = @o + LOWER(@c)
    END

    IF @c LIKE @w SET @f = 1

    SET @i = @i + 1
  END

  RETURN @o
END

Resultado:

dbo.ToProperCase('ALL UPPER CASE and    SOME lower ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ')
-----------------------------------------------------------------
All Upper Case and      Some lower Ää Öö Üü Éé Øø Cc Ææ